Child's Play

An interactive fiction by Stephen Granade (2007) - the Inform 7 source text

VOLUME 2 - On Changes to the World Model

Chapter 1 - New and Changed Actions, Which Extend or Restrict a Player's Range of Action

Instead of climbing, say "You can pull up on stuff and all but you can't do that climbing thing. Stupid short stubby legs."

Instead of climbing an enterable supporter, try entering the noun.

Instead of jumping, say "There is no way you are going to jump, you can barely crawl."

Instead of burning, say "It is too bad Fisher Price doesn't make a baby flamethrower, you would be all on that."

Instead of cutting or tying it to or swinging or buying, say "You are no good at that kind of stuff."

Instead of waving hands when the player is carrying something, say "You are busy holding stuff."

Instead of waving hands, say "You wave your hands and whee! it is fun."

Instead of sleeping, say "You are too good for naps!"

Instead of waking up, say "You are already awake, do not worry."

Instead of thinking, say "Thinking is like all you're doing these days, it is your job."

Instead of throwing at, say "There is no way, you can barely pick stuff up and you are no Cy Young or whatever."

Instead of attacking something, say "That might make you feel better but that is not the true baby way."

[The "if a parent person is present" checks aren't part of the rule so that the rules are fairly unspecific and thus are sorted low in the Instead rulebook.]
Instead of chewing a playmate:
    if a parent person is present, say "That is so not a good thing to do right in front of a parent unless you absolutely have to, for some reason biting is like the ultimate baby evil and you would get in trouble and not get your toy.";
    [Let one of the other rules catch this.]
    otherwise continue the action.

Instead of attacking or pushing or pulling a playmate:
    if a parent person is present, say "Hitting and pushing and pulling other babies when you're in front of parents is no good, they will take you away and you won't get your toy.";
    otherwise continue the action.

Instead of attacking or pushing or pulling or chewing a playmate:
    say "There is no parent around right now so you might get away with it at first but the parents would figure it out, if you want to hurt someone it really needs to be worth it and it needs to look like an accident."

Instead of tasting a playmate, say "From a distance parent's can't tell if you are planning on licking or biting another baby, it is best not to lick them at all."

Instead of attacking or pushing or pulling or chewing a parent person, say "It is no good kicking or biting a parent, it is better to rebel in less obvious ways."

Instead of tasting a parent person, say "Licking parents may seem like fun at first but soon they are telling their friends 'oh this is cute, watch this' and expecting you to do it on command."

Instead of pushing or pulling a playmate when the playmate is standing, say "That would certainly knock [the noun] over but that would get everyone in an uproar so it's best not to do it unless you really need to."

Instead of taking inventory when the player has no thing (this is the empty-handed inventory rule), say "Your hands are all empty."

Instead of taking inventory when the player is pulled up on something (called the item) (this is the pulled-up inventory rule), say "You are not carrying anything but you do have your hands full since you are pulled up on [the item]."

The empty-handed inventory rule is listed after the pulled-up inventory rule in the instead rulebook.

Instead of taking inventory when the player is gnawing something (called the masticated) and the player is pulled up on something (called the item), say "Your hands are full of [the item] and your mouth is full of [the masticated]."

A check kissing rule (this is the kissing other people rule):
    instead say "Your kisses are only for your family."
The kissing other people rule is listed before the block kissing rule in the check kissing rules.

Understand "squish [something]" or "smoosh [something]" as squeezing. Instead of squeezing something, say "It is hard enough to pick up things, squeezing is even harder and so don't worry about doing it, if it happens it happens."

Understand "lick [something]" as tasting.
Check tasting:
    if the noun is a person, instead say "You should stick with tasting things that aren't all wiggly and alive, you can get in trouble for that.";
    instead say "[Cap it-they of the noun] [if the noun acts plural]don't[otherwise]doesn't[end if] taste strange or anything."

Understand the command "walk" as something new. Understand the command "run" as something new.

Walking is an action applying to nothing. Understand "walk" or "run" as walking. Report walking: say "That is a developmental milestone you will reach someday but not today."

Reading is an action applying to one visible thing. Understand the command "read" as something new. Understand "read [something]" as reading. Report reading: say "It must be nice to read, the mom and the dad are always doing it, but you do not yet know how."

Wriggling is an action applying to nothing. Understand "wriggle" or "wiggle" or "squirm" as wriggling. Report wriggling: say "You wriggle around and that is probably cute and all but it is not really helpful."

Rolling over is an action applying to nothing. Understand "roll over" as rolling over. Report rolling over: say "Whatever, that may be impressive when you are five or six but you are like eleven or nearly twelve months old now."

Crawling aimlessly is an action applying to nothing. Understand "crawl" as crawling aimlessly.
Report crawling aimlessly: say "You can crawl around and all but to really get somewhere you have to pick a direction."

Understand "crawl [direction]" or "crawl to the [direction]" or "cruise [direction]" or "cruise to the [direction]" as going.

Understand "cruise [thing]" or "cruise to [thing]" as a mistake ("You can only cruise in a direction.")

Understand "get down" as exiting.

[Lump all actions that move the player together]
Going is being ambulatory. Entering something is being ambulatory. Exiting is being ambulatory. Getting off something is being ambulatory. Crawling aimlessly is being ambulatory. Rolling over is being ambulatory.

[Identify all actions that are talking and then prevent them.]
Talking to is an action applying to one visible thing. Understand "talk to [something]" as talking to.

Asking people for something is being talkative. Asking people about something is being talkative. Telling people about something is being talkative. Answering people that something is being talkative. Telling people about something is being talkative. Talking to something is being talkative. Saying yes is being talkative. Saying no is being talkative. Saying sorry is being talkative. Swearing obscenely is being talkative. Swearing mildly is being talkative. Singing is being talkative.

Instead of being talkative, say "You don't have speech down yet."

Instead of asking someone to try doing something (this is the can't command others rule), say "You don't have speech down yet."

[Pushing things around. Normally, pushing things doesn't print anything prior to the move, and then the pushed object isn't mentioned in the room description. This after rule, courtesy of Emily Short, fixes both of those problems.]
After going a direction (called way-pooshed) with something (called the pooshed-thing) (this is the pushing things to a new room rule): say "You shove and shove at [the pooshed-thing] [if the player is wearing the squid costume]with your floppy tentacles [end if]and eventually you get it moving to [the way-pooshed] and then you follow it."; move the pooshed-thing to the location; continue the action.

Instead of an actor going a direction with a pulled-up-on pushable between rooms thing (called the platform): if the actor is the player, say "That will not move as long as [if the player is pulled up on the platform]you are[otherwise]someone is[end if] all pulled up on it."; stop the action.

Instead of an actor going a direction with an occupied supporter (called the platform): if the actor is the player, say "That will not move as long as [if the player is on the platform]you are[otherwise]someone is[end if] all on it.";

Instead of pushing or pulling a pushable between rooms thing, say "[The noun] looks like it will move pretty far but you will have to say in what direction you want to push it."

Instead of taking a pushable between rooms supporter (this is the can't take pushable things rule), say "You tug on [the noun] but it is too big to take although it slides around just a little."

The can't take pushable things rule is listed before the can't take large things rule in the instead rulebook.

Understand "unfold [something]" as opening. Understand "fold [something]" as closing.

Understand "unzip [something]" as opening. Understand "zip [something]" as closing.

Understand "stick [other things] on/onto/to [something]" as putting it on.

[New commands]

Falling is an action applying to nothing. Understand "fall" or "fall down" or "fall over" as falling. Instead of falling, try going down.

Understand "shake [something]" or "rattle [something]" as waving.

Check an actor waving something carryable that is not held by the actor (this is the taking before shaking rule):
    if the actor is the player, say "(first taking [the noun])[command clarification break]";
    silently try the actor taking the noun;
    if the actor is not holding the noun, stop the action.

Check an actor waving something that is not carryable:
    if the actor is the player, say "[The noun] is big and so you cannot really shake [it-them].";
    stop the action.

After waving: say "You shake [the noun] and that is okay I guess."

Report someone waving something:
    if the person asked is present, instead say "[The person asked] shakes [the noun]."

Crying is an action applying to nothing. Understand "cry" or "scream" or "yell" or "wail" or "shriek" or "sob" or "fuss" or "pout" or "squall" as crying. Check crying: if the player is gnawing something, instead say player has a full mouth. Report crying: say "You make some noise but it doesn't really do anything for you right now."

Instead of crying when the player is in the baby-swing:
    say "You have already gotten in the baby swing, crying will do you no good now."

Instead of crying when Tabletime is happening, say "The mom says, 'I know you don't like them, but prunes are good for you.'"

Instead of crying when Zoe has your favorite toy, say "Crying to get the parents to take back the toy is a total Zoe trick, you will not stoop that low. Besides, you are so close to getting the toy it would be no good to have the mom take it away again."

Carry out crying when the baby-swing is in play and Picturetime is not happening:
    increment the cry count of the player by 1.

After crying when the cry count of the player is 1:
    say "You let out this sobbing wail and the mom says, 'Shh, it's okay.'"

After crying when the cry count of the player is 2:
    say "When you cry again the mom says, 'Shh. Calm down.'"

After crying when the cry count of the player is 3: say "This time you add a lot of tremolo to your crying and the mom says, 'You're not going to calm down, are you, kiddo? Do you need the swing?'"

[The bit with the dirty costume can also come up when upstanding using the mom when the player is wearing the squid costume and the squid costume is dirty. Synchronize the two rules in the event of changes.]
After crying when the cry count of the player is greater than 3:
    say "'Okay, kiddo, let's check you and make sure,' the mom says and scoops you up. 'Diaper's okay[run paragraph on]";
    if the player is wearing the squid costume and the squid costume is dirty begin;
        say ", though this costume is filthy.' She strips it from you, still talking, 'You're[run paragraph on]";
        record 5 points for "getting that evil squid costume off";
        remove the squid costume from play;
    otherwise;
        say ". You're[run paragraph on]";
    end if;
    say " not hungry. To the swing!' [run paragraph on]";
    if a playmate is in the baby-swing begin;
        say "Then she sees that [a random playmate in the baby-swing] is already in the swing and says 'I guess you'll have to hang on a sec' and she puts you back down.";
    otherwise;
        say "You're airlifted into the swing and the mom[if something is carried by the player] takes away [the list of things carried by the player] and[end if] straps you in. She turns it on, click click click, and then you are swinging[if the current speedness of the speed switch is hi] really high[end if].";
        now every thing that is carried by the player is in the location;
        if the player is gnawing something (called g), now g is not gnawed by anything;
        if the player is standing, now the player is not pulled up on anything;
        move the player to the baby-swing;
        now the baby-swing is on;
        now the cry count of the player is 0;
        the player stops swinging in six turns from now;
        if your favorite toy is not Parry-touched and the baby-swing is in the TKBUG Open Area and your favorite toy is in the bookcase, Parry potentially wanders by in four turns from now;
    end if.

At the time when Parry potentially wanders by:
    if your favorite toy is not Parry-touched begin;
        say "Parry comes wandering by with his water glass but he stops when he sees you swinging. He looks at your favorite toy. He looks at you. He looks at your toy[if Zoe and the player are co-located]. He looks at Zoe[end if]. He looks at how close you get to your favorite toy. When he is all done with his looking he casually leans against the bookcase and taps your toy. It totally falls a bit closer! He winks at you and heads on by[note Parry-knocks-the-toy].";
        now your favorite toy is Parry-touched;
    end if.

At the time when the player stops swinging:
    now the baby-swing is off;
    say "You look up and there is the mom, you are swinging toward her face and away, toward and away. She turns off the swing and gets you down and puts you on the floor before going back to her seat.";
    move the player to the location of the baby-swing;

Laughing is an action applying to nothing. Understand "laugh" or "coo" or "goo" or "smile" as laughing. Check laughing: if the player is gnawing something, instead say player has a full mouth. Report laughing: say "You smile and make a bubbly laugh noise, it is the thing you do that makes everyone say 'oh my goodness how cute!'"

Breathing is an action applying to nothing. Understand "breathe" as breathing. Report breathing: say "You do not have many things you can do, you are so young, but you don't have to think about breathing really, you do that automatically."

Breathing fast is an action applying to nothing. Understand "breathe fast" as breathing fast. Report breathing fast: say "You breathe fast for a minute and it makes you all light-headed."

Breathing slow is an action applying to nothing. Understand "breathe slow" or "breathe slowly" as breathing slow. Report breathing slow: say "You breathe slow but after a while you have to start breathing normally again."

[Adam Thornton made me add this]
Eliminating is an action applying to nothing. Understand "poop" or "pee" or "urinate" or "micturate" or "shit" as eliminating. Report eliminating: say "See for you to do that on command you'd have to be potty trained and you are not, that is just another way the man controls you."

Kicking is an action applying to nothing. Understand "kick" as kicking. Report kicking: say "You are all kick! kick! kick! but you don't have coordination or anything so it doesn't do much."

Kicking at is an action applying to one thing. Understand "kick [something]" or "kick at [something]" as kicking at. Report kicking at: say "You are way not coordinated enough to do that."

Playing with is an action applying to one thing. Understand "play with [something]" as playing with. Report playing with: say "That is way generic, you will need to be specific about what you want to do to play with something."

Flipping is an action applying to one thing. Understand "flip [something]" as flipping.
Check flipping:
    abide by the can't switch on unless switchable rule;
    if the noun is switched on, try switching off the noun instead;
    try switching on the noun instead.

Putting it under is an action applying to two things. Understand "put [other things] under [something]" or "push [other things] under [something]" or "wedge [other things] under [something]" as putting it under. Check putting it under: instead say "There is no real need to do that."

Rocking is an action applying to nothing. Understand "rock" as rocking. Report rocking: say "You are already totally rocking."

Spitting up is an action applying to nothing. Understand "spit" or "spit up" or "vomit" or "puke" or "slobber" or "drool" or "barf" or "ralph" as spitting up. Report spitting up: say "That would get your clothes all dirty and you do not need to do that right now."

Spitting up on is an action applying to one thing. Understand "spit up on [something]" or "spit on/in [something]" or "vomit on [something]" or "puke on [something]" or "slobber on [something]"or "drool on [something]"or "barf on [something]"or "ralph on [something]" as spitting up on. Report spitting up on: instead say "You do not need to get [the noun] all dirty right now."

Report spitting up on yourself: instead say "You do not need to get yourself all dirty right now."

Report spitting up on a person: instead say "It may be normal little baby behavior to drool and spit up all over parents and other babies but you are like eleven months old and now it would be unseemly."

Pushing it with is an action applying to two things. Understand "push [something] with [something preferably held]" or "lift [something] with [something preferably held]" or "raise [something] with [something preferably held]" or "hit [something] with [something preferably held]" as pushing it with.

[It's possible (pace Dan Shiovitz) that the player will type LIFT ME WITH FOOTSTOOL. Map that to upstanding with.]
Instead of pushing the player with something when the player's command includes "lift" or the player's command includes "raise", try upstanding using the second noun.

Check an actor pushing something with something carryable that is not held by the actor (this is the pick up objects before pushing with them rule):
    say "(first taking [the second noun])[command clarification break]";
    silently try taking the second noun;
    if the actor is not holding the second noun, stop the action.

Report pushing it with: say "Most of the time you can just push things without having to use something to do the pushing other than your little baby hands."

Speedness is a kind of value. The speednesses are lo, med, and hi.

Turning it to is an action applying to one thing and one speedness. Understand "turn [something] to [a speedness]" or "turn [something] on [a speedness]" or "flip [something] to [a speedness]" or "push [something] to [a speedness]" as turning it to. Check turning it to: say "You so cannot turn [the noun] like that."

[Get rid of the grammar "set x to y" (which matches the "setting it to" action) and attach it to the "turning it to" action.]
Understand the command "set" as something new. Understand "set [something] to [a speedness]" as turning it to.

[Remember where people were before they went somewhere, so we can report on it and can have a simple follow command.]
A person has a room called last location.

Carry out an actor going (this is the keeping track of people rule): change the last location of the actor to the location of the actor. The keeping track of people rule is listed first in the carry out going rulebook.

To decide if (youngster - a person) was recently present:
    if the last location of the youngster is the location, decide yes;
    decide no.

Following is an action applying to one visible thing. Understand "follow [any thing]" or "chase [any thing]" as following.

Check following when the noun is not a person (this is the can't follow inanimate objects rule): instead say "You really can only follow babies and also people."

Check following when the noun is the player (this is the can't follow yourself rule): instead say "That is easy, you are already here!"
Check someone following when the noun is the person asked: stop the action.

Check following when the noun is present (this is the can't follow someone present rule): if the actor is the player, say "That is easy, [the noun] is already here!"; stop the action.

Check someone following when the person asked and the noun are co-located: stop the action.

Check following when the last location of the noun is not the location (this is the can only follow at one remove rule): instead say "You can't remember where [the noun] went. Stupid little kid brain."

Check someone following when the last location of the noun is not the location of the person asked: stop the action.

Carry out an actor following:
    let the destination be the location of the noun;
    let aim be the best route from the location of the actor to the destination;
    if aim is not nothing begin;
        if the actor is the player begin;
            say "(heading [aim])[command clarification break]";
            try going aim;
        otherwise;
            [NPCs should go quietly]
            silently try the actor going aim;
        end if;
    end if.

Building is an action applying to one visible thing. Understand "build [any thing]" or "put together [any thing]" or "make [any thing]" as building.
Check building: instead say "You do not know how to build [the noun]."

[Fiddling reachability and the like when the player is held.]
A rule for reaching outside persons (this is the can't reach far-away objects when held rule):
    if the person reaching is the player, say "[The container in question] is holding you and so you are too far away.";
    deny access.

Instead of being ambulatory when the player is held by someone (called the holder), say "[The holder] is holding you and so you cannot really go anywhere from up here."

[If the player is held by someone and that someone has a "writing a paragraph about" rule, their paragraph won't be printed. This rule bypasses that as a default.]
A carry out looking rule (this is the room description paragraphs about enclosing people rule):
    if the player is enclosed by someone (called the holder), carry out the writing a paragraph about activity with the holder.

The room description paragraphs about enclosing people rule is listed after the room description paragraphs about objects rule in the carry out looking rulebook.

The source code to Child's Play is licensed under a Creative Commons NonCommercial Sampling Plus 1.0 License.