Child's Play

An interactive fiction by Stephen Granade (2007) - the Inform 7 source text

Section 4 - Parry Mason

Parry is a transparent man. The description is "That is Parry Mason, he is Watson Mason's dad. Normally Watson's mom Shari is here but she must be somewhere else so that is why Parry is here[if Parry encloses the backpack]. Right now he has the backpack and your favorite toy in his lap[end if]." Understand "mason", "leg", "legs", "parent", "foot" or "feet" as Parry. Parry is suitable for pulling up on. Parry can be puzzle-blocking or puzzle-allowing. Parry is puzzle-blocking.

Rule for writing a paragraph about Parry during Playtime:
    say "Parry's feet ";
    if someone (called the victim) is held by Parry, say "are flat on the floor and he is not rocking right now because he is holding [the victim] all gingerly.";
    otherwise say "keep leaving the floor as he rocks."

Rule for writing a paragraph about Parry when the player is standing during Playtime:
    say "Parry ";
    if someone (called the victim) is held by Parry, say "sits still in the rocking chair and holds [the victim] all carefully as if [it-they of the victim] might explode.";
    otherwise say "rocks slowly in the rocking chair."

Rule for writing a paragraph about Parry when the player is held by Parry during Playtime:
    say "Parry holds you gingerly high above the floor, wow you are tall."

Rule for writing a paragraph about Parry when Parry encloses the backpack during Playtime:
    say "Parry is trying to get the white onesie free of the backpack and he has your favorite toy in his lap."

Rule for writing a paragraph about Parry during Snacktime: say "You can see Parry or at least his legs over by the couch."

Rule for writing a paragraph about Parry when the player is standing during Snacktime: say "There is Parry on the couch."

Rule for writing a paragraph about Parry when Parry is puzzle-allowing during Snacktime: say "Parry is hovering over Lisa and Cassie and trying to be all helpful."

Rule for writing a paragraph about Parry during Picturetime: say "Parry is standing back a bit watching the picturetime commotion."

Rule for writing a paragraph about Parry during Costumetime: say "Those are Parry's feet dangling from the loveseat."

Rule for writing a paragraph about Parry when the player is standing during Costumetime: say "There is Parry on the loveseat."

Instead of upstanding using Parry:
    abide by the check upstanding using rulebook;
    say "Parry lets you get to your feet and then he puts you back on the floor and looks a bit guilty."

Instead of an actor upstanding using Parry during Playtime: try the actor upstanding using the gliding rocking chair.

Instead of Watson upstanding using Parry:
    abide by the check upstanding using rulebook;
    if Watson is present, say "Watson pulls up on Parry and Parry smiles down at Watson before reluctantly putting him back on the floor."

Instead of a playmate (called p) upstanding using Parry:
    abide by the check upstanding using rulebook;
    if p is present, say "[P] pulls up on Parry who puts [it-them] back down but looks guilty about it[if 1 out of 3], he is a big old pushover[end if]."

Instead of giving or showing something to Parry, say "He is too busy with talking and adults and other stuff."

[Change how things Parry carries are listed when he's holding the player.]
[Taken from http://groups.google.com/group/rec.arts.int-fiction/msg/2e13119bd6ea5580?dmode=source]
Rule for listing nondescript items of Parry when the player is enclosed by Parry:
say "Parry has [a list of marked for listing things which are carried by Parry] in his lap."

Carry out stopping chewing when the player is held by Parry during Playtime: move the noun to Parry.
Report stopping chewing when the player is held by Parry during Playtime: instead say "You spit out [the noun] with a 'pbuh' sound and since you are held by Parry it falls in his lap."

Carry out dropping when the player is held by Parry during Playtime: move the noun to Parry.
[This next rule is here solely because Jota tried filling Parry's lap with stuff.]
After dropping when the player is held by Parry during Playtime:
    let flag be 0;
    repeat with p running through the things which are carried by Parry begin;
        if p is not the noun and p is not the player begin;
            if flag is 0 begin;
                change flag to 1;
                say "You drop [the noun] into Parry's lap and he absentmindedly brushes off [the p]";
            otherwise;
                say " and [the p]";
            end if;
            move p to the location of Parry;
        end if;
    end repeat;
    if flag is 1 begin;
        say " onto the floor.";
        stop the action;
    end if;
    continue the action.
Report dropping when the player is held by Parry during Playtime: instead say "[The noun] falls into Parry's lap."

Instead of showing or giving something to Parry when the player is held by Parry during Playtime: say "You show [the noun] to Parry who is kinda distracted and so [it-they] fall[s] into Parry's lap."; move the noun to Parry; if the player is gnawing the noun, now the noun is not gnawed by anything.

Instead of going down or crying or wriggling or kicking or exiting when the player is held by Parry during Playtime: say "You wriggle and fuss a bit and [run paragraph on]"; make Parry put the player down.

The paper coaster is a small thing. The description is "A light spongy paper coaster for soaking up liquid from glasses." Understand "light" or "spongy" or "round" as the coaster.

Instead of an actor chewing the paper coaster:
    if the actor is the player begin;
        say "You shove the coaster into your mouth and it may be absorbent but it is no match for your drool. It disintegrates!";
    otherwise if the actor is present;
        say "[The actor] starts chewing on the paper coaster but its absorbency is no match for baby drool and it disintegrates!";
    end if;
    remove the paper coaster from play.

Instead of eating the paper coaster, try chewing the paper coaster.

The heavy tumbler is a container. The description is "The tumbler is thick glass and it holds water, it is left over from Parry snacking[if the tumbler is not on the cabinet top]. I guess Parry took it off the cabinet to take a drink from it and then forgot to put it back on the cabinet[otherwise]. It is way up on the cabinet[end if][if some thing is in the heavy tumbler]. Floating in the water you see [the contents of the heavy tumbler][end if]." Understand "water" or "thick" or "glass" or "cup" as the heavy tumbler. Rule for printing room description details of the heavy tumbler: stop.

To decide if the heavy tumbler is interactable: if Parry is puzzle-allowing and the tumbler is not on the cabinet top, decide yes; decide no.

Mentioning no mouth is a one-time deal.

To block messing around with the tumbler: say "You move towards the tumbler but Parry picks it up and says 'No, that's my glass[if mentioning no mouth has not occurred].' And then the mom chimes in, 'Hey, kiddo, no mouth! No mouth[end if].' Once you back off Parry puts the tumbler back down."

Before doing something other than examining when the heavy tumbler is acted upon and Parry is puzzle-blocking and the tumbler is not on the cabinet top (this is the Parry protects the tumbler rule), instead block messing around with the tumbler.

Instead of taking the heavy tumbler when the heavy tumbler is interactable, say "There is no way you're lifting it, it is really heavy."

Instead of pushing or pulling the heavy tumbler when the heavy tumbler is interactable, say "That thing is so thick on the bottom it is like eighty pounds and doesn't tip at all, the adults must all be weightlifters."

Before pushing the heavy tumbler to a direction when the heavy tumbler is interactable, instead say "That thing is so thick on the bottom it is like eighty pounds and doesn't tip at all, the adults must all be weightlifters."

Instead of inserting a small thing into the heavy tumbler when the heavy tumbler is interactable and the player is holding the noun:
    if the noun is the velcro jangly balls, instead say "Those velcro jangly balls are too useful to shove in there and probably lose them.";
    say "You shove [the noun] into the tumbler and it goes ploop into the water[if the noun is the paper coaster] and luckily enough it holds together instead of disintegrating[end if].";
    if the player is gnawing the noun, now the noun is not gnawed by anything;
    move the noun to the tumbler.

Instead of inserting something into the heavy tumbler when the heavy tumbler is interactable, say "[The noun] won't fit inside it."

Instead of inserting something into the heavy tumbler when the heavy tumbler is on a supporter and the player is standing, say "That would take more coordination than you have, you are no Kurt Thomas."

Instead of removing something from the heavy tumbler when the heavy tumbler is interactable, say "Now that [the noun] is wet you can't really get hold of it."

Instead of taking something that is in the heavy tumbler when the heavy tumbler is interactable, say "Now that [the noun] is wet you can't really get hold of it."

[Eating requires you take the tumbler, which won't happen, so I re-route using this before rule]
Before eating the heavy tumbler when the heavy tumbler is interactable and the player is not gnawing something, instead try drinking the heavy tumbler.

Instead of drinking or tasting or chewing or spitting up on the heavy tumbler when the heavy tumbler is interactable and the player is not gnawing something:
    say "You put your mouth on the edge of the glass but there is no way you will tip it enough to drink but at least you slobbered all over it.";
    now the tumbler is damp.

The source code to Child's Play is licensed under a Creative Commons NonCommercial Sampling Plus 1.0 License.