Child's Play

An interactive fiction by Stephen Granade (2007) - the Inform 7 source text

Chapter 1 - Goading

Goading is a scene. Goading begins when Suffocation ends. Goading ends when the player is pulled up on the footstool or the player is pulled up on the mom.

When Goading begins:
    say "You eye your favorite toy and the mom sees you doing it and scoops it up. 'No, no, we're going to try pulling up!' She is all the time trying to build your character or something. She waves the toy at you. 'Look! Look where I'm putting it!' She drops the toy on the footstool where you can't see it unless you're all pulled up, that is just no fair[note pulling-up].";
    now your favorite toy is on the footstool.

The introduction turn count is a number that varies. The introduction turn count is 0.

Every turn during Goading:
    increment the introduction turn count by 1;
    if the introduction turn count is less than 3, rule succeeds;
    change the introduction turn count to 0;
    choose row chatter count in the Table of Encouraging Messages;
    say "[message entry][paragraph break]";
    increment the chatter count by 1;
    if the chatter count is greater than the number of rows in the Table of Encouraging Messages
    begin;
        change the chatter count to 1;
        sort the Table of Encouraging Messages in random order;
    end if;

Table of Encouraging Messages
Message
"The mom sits there looking at you all expectantly."
"The mom points to the footstool. 'Give it a try! Go ahead! Pull up!'"
"The mom sighs and is all 'You were pulling up just yesterday[note disappointments].'"
"The mom mimes holding onto the footstool and lifting herself with it."

When Goading ends:
    say "The mom applauds, 'Way to go!' She looks at her watch and is all 'Whoops! Playgroup's about to arrive. You hang out here while mom goes and gets ready.' She stands up [if the player is pulled up on the mom]and dumps you on your diaper [end if]and steps over all of those pillows and you are stuck here now by yourself[note baby-containment].";
    if the player is pulled up on the mom begin;
        let go of the mom;
        record 5 points for "pulling up on the mom";
    otherwise;
        record 5 points for "pulling up on the footstool";
    end if;
    remove the mom from play;

The source code to Child's Play is licensed under a Creative Commons NonCommercial Sampling Plus 1.0 License.