Child's Play

An interactive fiction by Stephen Granade (2007) - the Inform 7 source text

Chapter 6 - Picturetime
Picturetime is a scene. Picturetime begins when Snacktime ends. Picturetime ends when the number of filled rows in the Table of Picturetime-Chatter is 0.
When Picturetime begins:
   [Clear out everyone's stuff]
   set the kids to a ground state;
   now every playmate is passive;
   now every playmate is in Onna Couch;
   now every parent person is in Onna Couch;
   now Jemison is impervious to fixation;
   remove the velcro jangly balls from play;
   remove the heavy tumbler from play;
   display chapter head "Chapter 3" with subhead "Picturetime";
   change chatter count to 0;
   change cry count of the player to 0;
   [Time for costumes!]
   now the squid costume is worn by the player;
   now the ladybug costume is worn by Zoe;
   now the bumblebee costume is worn by Jemison;
   now the pumpkin costume is worn by Cassie;
   now the bat costume is worn by Watson;
   say "It is like you are psychic because you don't get to keep the toy. The mom storms around the couch and scoops you up and grabs the toy. 'It's okay, Farina,' Marion says, 'accidents happen. Zoe and Jemison don't look hurt, just wet.' Several of the other parents are glaring at Parry, he looks all sheepish.
'Since the kids have to be changed anyway, let's take pictures!' Marion says.
'Sure, works for me,' Lisa says, and just like that everyone is getting their onesies taken off and instead they are being put in these Halloween costumes, and that would be okay except your squid costume is totally restrictive[note stupid-costumes].";
   move the player to Onna Couch.
When Picturetime ends:
   change chatter count to 0.
The squid costume is a wearable medium thing. The squid costume can be dirty or clean. The squid costume is clean. The description of the squid costume is "It is like a squid if a squid was all plush and powder blue and didn't have any suckers[if the player is wearing the squid costume]. You are wearing it and its tentacles cover your arms and hands[end if][if the squid costume is dirty]. It is all icky down the front from where you spit up on it[end if]." Understand "plush" or "powder" or "blue" or "tentacles" as the squid costume. Instead of taking off the squid costume, say "You cannot see how it comes off, maybe you will be stuck in it forever." Instead of chewing the squid costume, say "You gnaw on one of the tentacles a bit but it is not very satisfying and eating your way out of your costume is too impractical."
The costume-hint count is a number that varies. The costume-hint count is 0.
To check on giving a costume hint:
   increase the costume-hint count by 1;
   if the costume-hint count is 5, say ". You really have to get someone to take this costume off for you".
Instead of taking something when the player is wearing the squid costume (this is the squid costume lacks suckers for taking things rule):
   say "With this stupid costume on you cannot take anything, the fake tentacles are all in the way[note squid-costume]";
   check on giving a costume hint;
   say "."
Instead of upstanding using something when the player is wearing the squid costume (this is the squid costume lacks suckers for upstanding using rule):
   say "You would but the tentacles of your stupid squid costume are too slick[note squid-costume]";
   check on giving a costume hint;
   say "."
Instead of upstanding using a parent person (called target) when the player is wearing the squid costume (this is the parents find the squid costume cute rule), say "You can't pull up in the squid costume but you rub up against the legs of [the target] and get a look and a smile in response."
Instead of spitting up when the player is wearing the squid costume:
   if the squid costume is dirty begin;
   say "That is enough spitting up for now, the squid costume is good and dirty.";
   otherwise;
   say "You reach deep down inside you and bring up some of those stupid prunes the mom was feeding you and spit them up on the squid costume, making it all dirty[note spitting-up].";
   now the squid costume is dirty;
   end if.
Instead of spitting up on the squid costume, try spitting up.
Instead of showing or giving the squid costume to a parent person (called target) when the player is wearing the squid costume and the squid costume is dirty: try upstanding using the target.
[The squid costume can also come up when you cry when the cry count of the player is greater than 3. Synchronize the two rules in the event of changes.]
Instead of upstanding using the mom when the player is wearing the squid costume and the squid costume is dirty:
   say "You rub up against the legs of the mom and she looks down and says, 'Oh, oh, your costume is all dirty, kiddo.' She lifts you up and the next thing you know you are back on the ground and free of that evil squid costume.";
   record 5 points for "getting that evil squid costume off";
   remove the squid costume from play.
Instead of upstanding using a parent person (called target) when the player is wearing the squid costume and the squid costume is dirty:
   say "You rub up against the legs of [the target], who sees that you are dirty and says 'Uh, Farina,' and hands you over to the mom. The mom takes you and says, 'Oh, oh, your costume is all dirty, kiddo,' and the next thing you know you are back on the ground and free of that evil squid costume.";
   record 5 points for "getting that evil squid costume off";
   remove the squid costume from play.
The ladybug costume is a wearable medium thing. The description of the ladybug costume is "Black and red and cute all over, though it is not so cute when Zoe is wearing it." Understand "bug" as the ladybug costume.
The bumblebee costume is a wearable medium thing. The description of the bumblebee costume is "The tiny antennas and tiny wings totally make the costume." Understand "antenna" or "wing" as the bumblebee costume.
The pumpkin costume is a wearable medium thing. The description of the pumpkin costume is "Round but not so round that Cassie cannot zoom around in it."
The bat costume is a wearable medium thing. The description of the bat costume is "You can see how someone would think this was a fun idea but man, it just makes Watson look like a giant emo cupid."
Onna Couch is a room. "You don't get up on the couch all that much but now you are up here with everyone else so you can have your pictures taken." The printed name is "On the Couch".
Before being ambulatory in Onna Couch, instead say "You start to move and then there is the mom, she pushes you back in place. 'Whoa, kiddo, we've got to get a picture of everyone.'"
Instead of crying during Picturetime, say "The mom says, 'We're just taking a couple of pictures, kiddo. Hang in there.'"
Instead of crying when the chatter count is 9 during Picturetime, say "The mom says, 'We're about done!'"
The fake-couch is scenery in Onna Couch. Understand "gray" or "grey" or "couch" as the fake-couch. The description is "Grey and soft under you." The printed name is "grey couch".
Instead of spitting up when the player is in Onna Couch (this is the no spitting up during Picturetime rule): say "While it is sometimes fun to make the mom's life hard, all that would happen is that you would spit up and your costume would get dirty and the mom would try to clean up your costume and then she would put you back down on the couch for pictures and really who wants this picture taking to take any longer than it has to? After the parents have taken pictures, then you can go crazy with the spitting up."
Every turn during Picturetime:
   [chatter count is 0 to begin with so we skip the first turn]
   if chatter count is not 0 begin;
   choose row chatter count in the Table of Picturetime-Chatter;
   say "[chatter entry][paragraph break]";
   blank out the whole row;
   end if;
   increment chatter count by 1.
Before looking or examining or looking under or searching or reading or taking inventory when the chatter count is 8 during Picturetime:
   if the noun is not the white-and-red-spots, instead say "All you can see are these white-and-red spots."
[Since I don't have a good way to move items in and out through the chatter daemon, I'll fake the funk using a conditional Understand rule.]
The white-and-red-spots are scenery in Onna Couch. The description is "The spots are white and red and like you looked at the sun." Understand "white and red" or "white" or "red" or "spot" or "spots" or "sun" or "suns" as the white-and-red-spots when the chatter count is 8 and Picturetime is happening.
[The above rule about vision depends on the camera flashes going off on line 7 of the table. If you change its position, change the above rule.]
Table of Picturetime-Chatter
Chatter
"The mom says, 'That's an interesting costume Watson's wearing.' Watson must know he's being talked about, he ducks his head and looks sad."
"'We made it ourselves,' Parry replies."
"Becca laughs all loud. 'It's not very cheerful--whoops, hold on there Jemison.' Zoe must've pushed Jemison because he starts to topple sideways before Becca rescues him."
"Parry is all huffy, 'We wanted something different from the usual.'"
"'Does that thing have buttons? That'll make it fun to take off if he spits up on it,' Becca laughs again."
"Cassie bounces up and down next to you and you try to back away from her but your tentacles get in your way. 'Keep the kids together!' Lisa calls, pointing a small camera at all of you."
"Parry and the mom get you all in place on the couch. The mom dangles your favorite toy in front of all of you! You and Zoe stare raptly at it and then Parry says 'Now!' and it is like a thousand suns explode in front of you and all you can see are these white and red spots."
"As the spots clear you see Watson has pitched face first into the couch. Zoe is busy tugging on Jemison's wings and Cassie is chewing on one of your tentacles. 'Hope no one wanted another picture!' Becca says."
"The parents give up and take you all off the couch. As the mom puts you down she stops by the bookcase and puts your toy up there. 'Maybe next year they'll sit still,' Lisa sighs, and Parry just snorts."

The source code to Child's Play is licensed under a Creative Commons NonCommercial Sampling Plus 1.0 License.